mkdir C:\tftp
call copype.cmd x86 C:\Tftp\Boot 
move ISO\boot\boot.sdi boot.sdi
imagex /mount winpe.wim 1 mount
copy mount\Windows\Boot\PXE\pxeboot.n12 pxeboot.n12
copy mount\Windows\Boot\PXE\bootmgr.exe bootmgr.exe
copy mount\Windows\System32\bcdedit.exe bcdedit.exe
mkdir Fonts
xcopy /s mount\Windows\Boot\Fonts c:\tftp\Boot\Fonts
bcdedit -createstore BCD
set BCDEDIT=bcdedit -store BCD
%BCDEDIT% -create {ramdiskoptions} -d "Ramdisk options"
%BCDEDIT% -set {ramdiskoptions} ramdisksdidevice boot
%BCDEDIT% -set {ramdiskoptions} ramdisksdipath \Boot\boot.sdi
for /f "tokens=3" %%a in ('%BCDEDIT% -create -d "Windows PE" -application osloader') do set GUID=%%a
%BCDEDIT% -set %GUID% systemroot \Windows
%BCDEDIT% -set %GUID% detecthal Yes
%BCDEDIT% -set %GUID% winpe Yes
%BCDEDIT% -set %GUID% osdevice ramdisk=[boot]\Boot\winpe.wim,{ramdiskoptions}
%BCDEDIT% -set %GUID% device ramdisk=[boot]\Boot\winpe.wim,{ramdiskoptions}
%BCDEDIT% -create {bootmgr} -d "Windows Boot Manager"
%BCDEDIT% -set {bootmgr} timeout 30
%BCDEDIT% -set {bootmgr} displayorder %GUID%
del /Q bcdedit.exe
del /Q etfsboot.com
imagex /unmount mount
rmdir /Q mount
rmdir /S /Q ISO